Bifurcations

Example of Tangent (or Saddle-Node) Bifurcation

Here is the function we will be looking at.

Q[c_,x_]:=x^2+c

A tangent bifurcation occurs at (Subscript[c, 0])=(1/4).

c=1/2;
Panel[Column[{Row[{Slider[Dynamic[c],{0,1/2}]," c="Dynamic[c]}],Dynamic[Plot[{x,Q[c,x]},{x,0,1},AspectRatio->Automatic,PlotRange->{0,1},ImageSize->{500,500}]]}]]

We will now compute the bifurcation diagram

Clear[c,x]
sol=Solve[Q[c,x]==x,x]
Plot[{x/.sol[[1]],x/.sol[[2]]},{c,0,0.5},PlotRange->{0,1},AspectRatio->Automatic]

Example of Period Doubling Bifurcation

Here is the function we will be looking at.

F[μ_,x_]:=μ x (1-x)

A period doubling bifurcation occurs at (Subscript[μ, 0])=3.

μ=2;
Panel[Column[{Row[{Slider[Dynamic[μ],{2,4}]," μ="Dynamic[μ]}],Dynamic[Plot[{x,F[μ,x]},{x,0,1},AspectRatio->Automatic,PlotRange->{0,1},ImageSize->{500,500}]]}]]

Same diagram, but now with the squared map drawn:

μ=2;
Panel[Column[{Row[{Slider[Dynamic[μ],{2,4}]," μ="Dynamic[μ]}],Dynamic[Plot[{x,F[μ,x],F[μ,F[μ,x]]},{x,0,1},AspectRatio->Automatic,PlotRange->{0,1},ImageSize->{500,500}]]}]]

Same thing, but zoomed in to the interval [1/2,1].

μ=2;
Panel[Column[{Row[{Slider[Dynamic[μ],{2,4}]," μ="Dynamic[μ]}],Dynamic[Plot[{x,F[μ,x],F[μ,F[μ,x]]},{x,1/2,1},AspectRatio->Automatic,PlotRange->{1/2,1},ImageSize->{500,500}]]}]]

We will now compute the bifurcation diagram including points of period 1 and 2.

Clear[μ,x]
sol1=Solve[F[μ,x]==x,x]
sol2=Solve[F[μ,F[μ,x]]==x,x]

Plot[{((-1+μ)/μ),{x/.sol2[[3]],x/.sol2[[4]]}},{μ,2,4},PlotRange->{0,1},ImageSize->{500}]

We will now comute the Bufurcation diagram including points of period 1, 2 and 4.

Clear[μ,x]
sol3=Solve[F[μ,F[μ,F[μ,F[μ,x]]]]==x,x];
Plot[x/.sol3,{μ,2,4},PlotRange->{0,1},ImageSize->{500}]